AutoHotKeyで、Opera10.60以降のタブ切り替えをホイールのみで可能にした+α。

 Ctrl+Tabで表示されるサムネイルを有効利用したくなったのでやってみた。なんかAHK祭りだな。

 「特定位置でホイールを回すとCtrl+Tabを出力してタブを切り替える」機能自体は相変わらず。ただ今回のは、ホイールを回してる間はタブ一覧が表示されっぱなしで、実際には切り替わらない。ホイールに触れず、しばらく放置すると切り替わる。これにより、「タブの切り替えにサムネイルを表示」設定にしておくと、軽快にタブを縦断できるって寸法よ。

;--------------------------------------------------
; Opera
;--------------------------------------------------
#IfWinActive ahk_class OperaWindowClass

OpTabCheck(){
  MouseGetPos, PosX, PosY, , Ctrl
  if (0 <= PosY) && (90 >= PosY)
    return 1
  return 0
}

OpTabRelease:
  OpTabSelect := 0
  send, {Ctrl Up}
return

$~WheelUp::
  if(OpTabCheck())
  {
    SetTimer, OpTabRelease, -800
    OpTabSelect := 1
    send, {Ctrl Down}+{Tab}
  }
return

$~WheelDown::
  if(OpTabCheck())
  {
    SetTimer, OpTabRelease, -800
    OpTabSelect := 1
    send, {Ctrl Down}{Tab}
  }
return

$^WheelUp::
  if (OpTabSelect)
  {
    SetTimer, OpTabRelease, -800
    send, +{Tab}
  }
  else
  {
    send, ^{WheelUp}
  }
return

$^WheelDown::
  if (OpTabSelect)
  {
    SetTimer, OpTabRelease, -800
    send, {Tab}
  }
  else
  {
    send, ^{WheelDown}
  }
return

 800のところを短くすれば、すぐに切り替わるようになる。逆に、もっと伸ばして、キー入力で切り替わるようにしてもいい。このままでも右クリックすれば行けるっぽい。ただその場合、「タイマー切れるまでCtrlは押しっぱなし」ということに注意。
 増やすにしろ減らすにしろ、ハイフンははずしちゃダメ。

 *WheelUp::とかにすればWheelUp::と^WheelUp::を分ける必要はないのだが、そうするとタブ切り替えたいだけなのにCtrl+ホイールでページの表示倍率変えちゃうことがあるなーという理由でやめた。――タブバー上からレンダリングペインまで、ホイール回しながら移動してこないとそんなことにはならないけど……。


[PR]
by lordnoesis | 2011-03-17 12:27 | テクノロジ | Trackback | Comments(0)
トラックバックURL : http://poimono.exblog.jp/tb/16065667
トラックバックする(会員専用) [ヘルプ]
※このブログはトラックバック承認制を適用しています。 ブログの持ち主が承認するまでトラックバックは表示されません。
名前
URL
画像認証
削除用パスワード

※このブログはコメント承認制を適用しています。ブログの持ち主が承認するまでコメントは表示されません。

ブログトップ | ファンになる